ExcelVBA函数:将单元格区域保存为文本文件，并备份不同版本

在构建数据模型过程中，经常需要保存特定单元格区域，包括调整相应的行和列。

保存文件，包括excel、txt、csv等格式。

同时，往往需要进行间隔性备份，以保留不同的版本。

对于上述要求，相应Sub函数如下：

Sub 将单元格区域保存到文本文件并间隔日期进行备份(objRange As Range, strTxtFileName As String, objBackupFold As String)
    
    Dim row As Range
    Dim cell As Range
    Dim strText As String
    Dim rowText As String
    Dim latestModifiedDate As Date
    Dim file As Object
    Dim fso As Object
    Dim folder As Object
    Dim twoWeeksAgo As Date
    Dim backupFileName As String
    Dim objRangeSaved As Range

    ' 确保 objRange 只有三列，3，也可以作为参数。

    If objRange.Columns.Count > 3 Then
        Set objRangeSaved = objRange.Resize(objRange.Rows.Count, 3)
    Else
        Set objRangeSaved = objRange
    End If

    ' 遍历
    For Each row In objRangeSaved.Rows
        rowText = ""
        For Each cell In row.Cells
            rowText = rowText & cell.Text & vbTab
        Next cell
        ' 去掉行末尾多余的 vbTab，添加回车符 vbCrLf
        If Len(rowText) > 0 Then
            rowText = Left(rowText, Len(rowText) - 1) 
        End If
        strText = strText & rowText & vbCrLf
    Next row

    ' 这个在前面文章中有该函数
    SaveTextToFile strTxtFileName, strText

    ' 检查备份文件：最新修订日期
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set folder = fso.GetFolder(objBackupFold)
    twoWeeksAgo = Now - 14
    latestModifiedDate = DateValue("1900-01-01") 

    For Each file In folder.Files
        If file.DateLastModified > latestModifiedDate Then
            latestModifiedDate = file.DateLastModified
        End If
    Next file

    ' 超过了两周，则创建备份 
    If latestModifiedDate < twoWeeksAgo Then
        backupFileName = objBackupFold & "\Backed_" & Format(Now, "yyyyMMddHHmmss") & ".txt"
        SaveTextToFile backupFileName, strText
    End If
 
    Set file = Nothing
    Set folder = Nothing
    Set fso = Nothing

End Sub